Oracle
 sql >> Base de données >  >> RDS >> Oracle

Comment vérifier si le fichier est une image à l'aide de PL/SQL ?

Dans cet article de blog, je partage une fonction avec laquelle vous pouvez vérifier si un fichier est un fichier image ou n'utilise pas PL/SQL. Le programme vérifiera le fichier en lisant son en-tête et non le nom d'extension du fichier. Actuellement, la fonction peut identifier trois types d'images qui sont JPG, PNG et GIF.

Fonction PL/SQL pour vérifier si le fichier est un fichier image

La fonction PL/SQL suivante lira l'en-tête du fichier, puis renverra le type d'image dans le type de données varchar2. La fonction get_image_type prend deux arguments, et ils sont les suivants :

  1. Objet d'annuaire Oracle (comme i_dir) Apprenez à créer un objet d'annuaire Oracle.
  2. Nom du fichier (as i_file) le fichier doit exister dans le répertoire.
CREATE OR REPLACE FUNCTION get_image_type (i_dir    IN VARCHAR2,
                                           i_file   IN VARCHAR2)
   RETURN VARCHAR2
AS
   l_bfile       BFILE;
   l_blob        BLOB;
   l_file_type   VARCHAR2 (50);
BEGIN
   DBMS_LOB.createtemporary (l_blob, FALSE);
   l_bfile := BFILENAME (i_dir, i_file);
   DBMS_LOB.fileopen (l_bfile, DBMS_LOB.file_readonly);
   DBMS_LOB.loadfromfile (l_blob, l_bfile, DBMS_LOB.getlength (l_bfile));
   DBMS_LOB.fileclose (l_bfile);

   IF RAWTOHEX (DBMS_LOB.SUBSTR (l_blob, 8, 1)) = '89504E470D0A1A0A'
   THEN
      l_file_type := 'PNG';
   ELSIF DBMS_LOB.SUBSTR (l_blob, 3, 1) = '474946'
   THEN
      l_file_type := 'GIF';
   ELSIF RAWTOHEX (DBMS_LOB.SUBSTR (l_blob, 3, 1)) = 'FFD8FF'
   THEN
      l_file_type := 'JPG';
   ELSE
      l_file_type := 'The file is not an image.';
   END IF;

   RETURN l_file_type;
EXCEPTION
   WHEN OTHERS
   THEN
      IF DBMS_LOB.fileisopen (l_bfile) = 1
      THEN
         DBMS_LOB.fileclose (l_bfile);
      END IF;

      DBMS_LOB.freetemporary (l_blob);
      RETURN 'The file does not exists.';
END get_image_type;

Tester

Dans le programme PL/SQL ci-dessous, modifiez l'objet de répertoire Oracle MY_FILES avec votre objet de répertoire et modifiez le nom du fichier avec le fichier disponible dans l'emplacement du répertoire MY_FILES.

SET SERVEROUTPUT ON;

DECLARE
   i_image_type   VARCHAR2 (50);
BEGIN
   i_image_type := get_image_type ('MY_FILES', 'oracle-logo-gif-to-use.gif');

   IF i_image_type IN ('JPG', 'GIF', 'PNG')
   THEN
      DBMS_OUTPUT.put_line ('The file is a valid ' || i_image_type || ' image.');
   ELSE
      DBMS_OUTPUT.put_line (i_image_type);
   END IF;
END;
/

Sortie

The file is a valid GIF image.
PL/SQL procedure successfully completed.

Voir aussi :

  • Comment insérer un fichier dans une table Oracle à l'aide de PL/SQL ?