Oracle
 sql >> Base de données >  >> RDS >> Oracle

Comment enregistrer BLOB en tant que fichier en PL/SQL ?

Ici, je donne un exemple pour enregistrer des données BLOB sous forme de fichier en PL/SQL. Les données BLOB, vous pouvez les obtenir à partir de la table ayant une colonne BLOB, ou vous pouvez les obtenir à partir d'un fichier sur le disque.

Exemple de fonction PL/SQL pour enregistrer BLOB en tant que fichier

La procédure ci-dessous prend les trois arguments suivants :

  1. Nom de l'objet d'Oracle Directory (comme i_dir).
  2. Enregistrer sous le nom de fichier (as i_file).
  3. Données BLOB (comme i_blob).
CREATE OR REPLACE PROCEDURE blob_to_file (i_dir    IN VARCHAR2,
                                          i_file   IN VARCHAR2,
                                          i_blob   IN BLOB)
AS
   l_file       UTL_FILE.file_type;
   l_buffer     RAW (32767);
   l_amount     BINARY_INTEGER := 32767;
   l_pos        INTEGER := 1;
   l_blob_len   INTEGER;
BEGIN
   l_blob_len := DBMS_LOB.getlength (i_blob);

   l_file :=
      UTL_FILE.fopen (i_dir,
                      i_file,
                      'WB',
                      32767);

   WHILE l_pos < l_blob_len
   LOOP
      DBMS_LOB.read (i_blob,
                     l_amount,
                     l_pos,
                     l_buffer);
      UTL_FILE.put_raw (l_file, l_buffer, TRUE);
      l_pos := l_pos + l_amount;
   END LOOP;

   UTL_FILE.fclose (l_file);
EXCEPTION
   WHEN OTHERS
   THEN
      IF UTL_FILE.is_open (l_file)
      THEN
         UTL_FILE.fclose (l_file);
      END IF;

      RAISE;
END blob_to_file;

Tester

Le bloc PL/SQL suivant appellera la procédure ci-dessus en transmettant l'objet de répertoire Oracle, le nom de fichier et les données BLOB. Pour les données BLOB, j'utilise la fonction GET_BLOB pour laquelle j'ai donné un exemple dans mon précédent article de blog :Obtenir BLOB à partir d'un fichier en PL/SQL. Dans le cas ci-dessous, il obtiendra les données BLOB d'un fichier myfile.jpg à partir de l'emplacement MY_DIR et les enregistrera dans le fichier abc.jpg à l'emplacement IMG_DIR.

DECLARE
   f_blob   BLOB;
BEGIN
   /* check the above mentioned link for get_blob function example */
   f_blob := get_blob ('MY_DIR', 'myfile.jpg');
   /* now pass the blob to blob_to_file procedure to save it as a file */
   blob_to_file ('IMG_DIR', 'abc.jpg', f_blob);
END;

Vous pouvez maintenant vérifier l'emplacement du répertoire IMG_DIR pour le fichier créé via BLOB.

Voir aussi :

  • Comment créer un objet d'annuaire Oracle ?
  • Apprenez à extraire des données BLOB d'Oracle Table à l'aide de Toad