SQL Server 2008 et comparaison des caractères Unicode

D'accord, donc un peu plus de recherche montre que cela est presque certainement dû à un caractère plus récent, car cela fonctionne également avec les équivalents sql server 2008 du classement latin, mais pas les anciennes versions, c'est-à-dire fonctionne avec Latin1_General_100_CI_AS , mais pas avec Latin1_General_CI_AS . Pour obtenir une liste complète des classements qui comparent correctement ces chaînes, j'ai utilisé :

IF OBJECT_ID('Tempdb..#T') IS NOT NULL
    DROP TABLE #T;
IF OBJECT_ID('Tempdb..#V') IS NOT NULL
    DROP TABLE #V;

CREATE TABLE #V (A NVARCHAR(50), B NVARCHAR(50));
INSERT #V (A, B) VALUES (N'it᧠', N'it');

CREATE TABLE #T (Collation VARCHAR(500), Match BIT);

DECLARE @SQL NVARCHAR(MAX) = (SELECT N'INSERT #T (Collation, Match) 
                                        SELECT ''' + Name + ''', CASE WHEN A = B COLLATE ' + name + ' THEN 1 ELSE 0 END
                                        FROM    #V;'
                                FROM sys.fn_helpcollations()
                                FOR XML PATH(''), TYPE
                            ).value('.', 'NVARCHAR(MAX)');

EXECUTE sp_executesql @SQL;

SELECT  *
FROM    #T
WHERE   Match = 0;