Comment afficher les résultats d'une procédure en dehors de celle-ci dans Oracle

Pour tester la procédure que vous avez montrée, vous feriez quelque chose comme :

declare
  l_id hr_position.id%type;
  l_group_name hr_position.group_name%type;
  l_group_level hr_position.group_level%type;
begin
  drill_record_position('D', l_id, l_group_name, l_group_level);
  dbms_output.put_line(l_id ||':'|| l_group_name ||':'|| l_group_level);
end;
/

Mais cela - ou plus précisément, votre procédure - ne fonctionne que s'il existe exactement une ligne dans le jeu de résultats de la requête pour le type de valeur transmis. Il semble que vous vous attendiez à plusieurs lignes (ce qui entraînerait trop de lignes), mais il pourrait également y en avoir non (ce qui entraînerait l'absence de données trouvées).

Donc, il semble vraiment que votre question devrait porter sur la façon d'écrire votre procédure afin qu'elle fonctionne avec l'une des méthodes de récupération/test que vous avez essayées.

Si votre procédure doit renvoyer plusieurs lignes, elle peut utiliser un curseur de référence, par exemple :

create or replace procedure drill_record_position (
  p_record_type in varchar2,
  p_ref_cursor out sys_refcursor
)
as
begin
  open p_ref_cursor for
    select hr.id, hr.group_name, hr.group_level
    from hr_position hr
    join drill_position dp
    on hr.id = dp.id
    where dp.typevalue = p_record_type;
end drill_record_position;
/

que vous pourriez ensuite tester avec quelque chose comme :

declare
  l_ref_cursor sys_refcursor;
  l_id hr_position.id%type;
  l_group_name hr_position.group_name%type;
  l_group_level hr_position.group_level%type;
begin
  drill_record_position('D', l_ref_cursor);
  loop
    fetch l_ref_cursor into l_id, l_group_name, l_group_level;
    exit when l_ref_cursor%notfound;
    dbms_output.put_line(l_id ||':'|| l_group_name ||':'|| l_group_level);
  end loop;
  close l_ref_cursor;
end;
/

Vous pouvez également le faire en tant que fonction, ce qui pourrait être plus facile à utiliser depuis votre application :

-- drop procedure drill_record_position;

create or replace function drill_record_position (p_record_type in varchar2)
return sys_refcursor as
  l_ref_cursor sys_refcursor;
begin
  open l_ref_cursor for
    select hr.id, hr.group_name, hr.group_level
    from hr_position hr
    join drill_position dp
    on hr.id = dp.id
    where dp.typevalue = p_record_type;
  return l_ref_cursor;
end drill_record_position;
/

declare
  l_ref_cursor sys_refcursor;
  l_id hr_position.id%type;
  l_group_name hr_position.group_name%type;
  l_group_level hr_position.group_level%type;
begin
  l_ref_cursor := drill_record_position('D');
  loop
    fetch l_ref_cursor into l_id, l_group_name, l_group_level;
    exit when l_ref_cursor%notfound;
    dbms_output.put_line(l_id ||':'|| l_group_name ||':'|| l_group_level);
  end loop;
  close l_ref_cursor;
end;
/

Vous pouvez également le faire avec des collections et une fonction en pipeline, ce qui demande plus de travail à configurer :

create type t_drill_obj as object (
   -- use your real data types...
  id number,
  group_name varchar2(10),
  group_level number
)
/

create type t_drill_tab as table of t_drill_obj
/

create or replace function drill_record_position (p_record_type in varchar2)
return t_drill_tab pipelined as
begin
  for l_row in (
    select t_drill_obj(hr.id, hr.group_name, hr.group_level) as obj
    from hr_position hr
    join drill_position dp
    on hr.id = dp.id
    where dp.typevalue = p_record_type
  )
  loop
    pipe row (l_row.obj);
  end loop;
  return;
end drill_record_position;
/

mais vous pouvez l'appeler dans le cadre d'une autre requête, et même joindre le résultat si vous en avez besoin :

select * from table(drill_record_position('D'));