Groovy Oracle Stored Proc - index de colonne invalide

Le code suivant peut vous aider à obtenir la variable de SYS_REFCURSOR du bloc anonyme Oracle.

Nous devons nous concentrer sur quelques détails clés :

1. Classe groovy.sql.Sql n'a pas de OutParameter correspondant et nous le faisons manuellement en tant que CURSOR_PARAMETER et passez-le à sql.call méthode
2. Considérez que le bloc commence par {call DECLARE et se termine par END } sans point-virgule après END. Sinon, nous pouvons obtenir une SQLException mal reconnaissable au visage.
3. Les points d'interrogation ? à l'intérieur de sqlString sont des emplacements pour les liaisons de paramètres. Les liaisons sont faites dans l'ordre naturel en prenant les valeurs de parametersList .
   • Dans cet exemple, nous avons la seule liaison, donc le ? se lie avec CURSOR_PARAMETER en traitant la valeur comme OUT paramètre de type passé ;
4. Il n'y a qu'une seule entrée en fermeture après sql.call et ResultSet rs fournir des lignes de curseur my_cur déclaré en bloc anonyme.
5. Nous pouvons simplifier sqlString en utilisant une fonction renvoyant SYS_REFCURSOR au lieu d'une procédure avec OUT paramètre. Cela pourrait donc ressembler à ceci "{call BEGIN ? := MY_FUNC(); END}" ou même "{? = call MY_FUNC()}"

import groovy.sql.OutParameter
import groovy.sql.Sql
import oracle.jdbc.OracleTypes

import java.sql.ResultSet

def driver = 'oracle.jdbc.driver.OracleDriver'
def sql = Sql.newInstance('jdbc:oracle:thin:@my-server:1521:XXX', 'usr', 'psw', driver)

// special OutParameter for cursor type
OutParameter CURSOR_PARAMETER = new OutParameter() {
    public int getType() {
        return OracleTypes.CURSOR;
    }
};

// look at some ceremonial wrappers around anonymous block
String sqlString = """{call
    DECLARE
      my_cur SYS_REFCURSOR;
    BEGIN
        STORED_PROCEDURE_NAME(my_cur);
        ? := my_cur;
    END
}
""";

// the order of elements matches the order of bindings
def parametersList = [CURSOR_PARAMETER];


// rs contains the result set of cursor my_cur
sql.call(sqlString, parametersList) { ResultSet rs ->
  while (rs.next()) {
      println rs.getString("my_column")
  }
};

PS Et merci pour la question.