Comment diviser une chaîne en PL/SQL ?

Dans cet article, je donne un exemple de fonction que j'utilise principalement pour diviser une chaîne en PL/SQL. Surtout, lorsque j'écris un programme pour importer un fichier délimité. Voici cette fonction et un exemple d'utilisation.

Fonction PL/SQL pour fractionner une chaîne

Cette fonction prend quatre paramètres, et les détails de ces paramètres sont comme ci-dessous :

1. Source_String  :Chaîne à diviser
2. Champ_Position  :Position du délimiteur
3. Non résilié :False par défaut, mais si vous passez True, alors il ajoutera le délimiteur spécifié à la fin de la chaîne.
4. Séparateur :La valeur par défaut est la virgule ',', vous pouvez passer n'importe quel autre délimiteur.

CREATE OR REPLACE FUNCTION GetString (
Source_string IN VARCHAR2,
Field_position IN NUMBER,
UnTerminated IN BOOLEAN DEFAULT FALSE,
Delimiter IN VARCHAR2 DEFAULT ',')
RETURN VARCHAR2
IS
iPtrEnd PLS_INTEGER := 0;
iPtrStart PLS_INTEGER := 0;
vcSourceStrCopy VARCHAR2 (4000) := Source_string;
BEGIN
IF UnTerminated
THEN
vcSourceStrCopy := vcSourceStrCopy || Delimiter;
END IF;

IF Field_Position > 1
THEN
iPtrStart :=
INSTR (vcSourceStrCopy,
Delimiter,
1,
Field_Position - 1)
+ LENGTH (Delimiter);
ELSE
iPtrStart := 1;
END IF;

iPtrEnd :=
INSTR (vcSourceStrCopy,
Delimiter,
1,
Field_Position);
RETURN SUBSTR (vcSourceStrCopy, iPtrStart, (iPtrEnd - iPtrStart));
END GetString;

Exemple :Utiliser cette fonction dans un programme PL/SQL

SET SERVEROUTPUT ON;

DECLARE
   v_string      VARCHAR2 (1000) := 'Java|.Net|C|Oracle|PHP';

   TYPE t_string IS TABLE OF VARCHAR2 (1000)
                       INDEX BY BINARY_INTEGER;

   t_str_array   t_string;
BEGIN
   FOR i IN 1 .. 5
   LOOP
      t_str_array (i) :=
         getstring (v_string,
                    i,
                    TRUE,
                    '|');
   END LOOP;

   FOR j IN t_str_array.FIRST .. t_str_array.LAST
   LOOP
      DBMS_OUTPUT.put_Line (t_str_array (j));
   END LOOP;
END;
/

Sortie :

Java
.Net
C
Oracle
PHP
PL/SQL procedure successfully completed.

Voir aussi :

• Exporter des données au format JSON à l'aide de PL/SQL dans Oracle 11g
• Programme PL/SQL pour imprimer les détails des employés