Créer un travail d'agent SQL Server à l'aide de T-SQL

L'Agent SQL Server est un service Microsoft Windows qui exécute des tâches administratives planifiées, appelées tâches. dans SQL Server.

T-SQL inclut une grande collection de procédures stockées qui traitent des travaux de l'Agent SQL Server.

Ici, nous en utiliserons certains pour créer et planifier une tâche de l'Agent SQL Server.

Vous pouvez également créer des travaux de l'Agent SQL Server via l'interface graphique (dans SSMS) si vous préférez.

Activer les XP d'agent

Si c'est la première fois que vous créez une tâche de l'Agent SQL Server sur votre instance SQL Server, vous devrez probablement activer les procédures stockées étendues de l'Agent SQL Server (Agent XP).

Voici comment le faire en utilisant T-SQL, et voici comment le faire en utilisant l'interface graphique SSMS.

Une fois que vous avez fait cela, vous pouvez continuer et créer un travail SQL Server Agent comme celui ci-dessous.

Exemple

Voici un exemple du code utilisé pour créer et planifier une tâche de l'Agent SQL Server.

USE msdb;  
GO  
EXEC sp_add_job  
    @job_name = N'BackupPetHotelDB' ;  
GO  
EXEC sp_add_jobstep  
    @job_name = N'BackupPetHotelDB',  
    @step_name = N'Run the backup',  
    @subsystem = N'TSQL',  
    @command = N'BACKUP DATABASE [PetHotel] TO DISK = N''C:\Backups\PetHotel.bak'' WITH CHECKSUM',
    @retry_attempts = 5,  
    @retry_interval = 5;  
GO
EXEC sp_add_schedule 
    @schedule_name = N'RunDailyAM',
    @freq_type = 4,
    @freq_interval = 4,
    @active_start_time = 041000;
GO  
EXEC sp_attach_schedule  
   @job_name = N'BackupPetHotelDB',  
   @schedule_name = N'RunDailyAM';  
GO  
EXEC sp_add_jobserver  
    @job_name = N'BackupPetHotelDB';  
GO

Ici, nous utilisons cinq procédures stockées pour créer et planifier le travail. La plupart de ces procédures acceptent beaucoup plus d'arguments (facultatifs) que ce que j'ai utilisé dans cet exemple. Pour une liste complète des arguments disponibles pour chaque procédure, consultez les liens dans le tableau ci-dessous.

Ces procédures stockées sont dans le msdb base de données, et vous pouvez voir que nous avons défini msdb comme base de données actuelle avant de les exécuter. Alternativement, vous pouvez les qualifier avec le nom de la base de données (par exemple msdb.dbo.sp_add_job... , etc.)

Le tableau suivant fournit un aperçu rapide de chaque procédure.

Afficher le travail

Vous pouvez utiliser le sp_help_job procédure stockée dans msdb base de données pour afficher les travaux de l'Agent SQL Server qui ont été créés sur le serveur.

EXEC sp_help_job;

Voici à quoi cela ressemble sur ma machine de test :

Dans ce cas, il y a trois emplois.

Vous pouvez également voir les travaux dans l'Explorateur d'objets lorsque vous avez le SQL Server Agent> Jobs nœud développé.

Le sp_help_job procédure stockée vous permet de fournir le nom ou l'ID d'un travail afin d'obtenir des informations plus détaillées sur ce travail.

Exemple :

EXEC sp_help_job @job_name= 'BackupPetHotelDB';

Résultat :

Les résultats sont séparés en détails de la tâche principale, les étapes de la tâche, les planifications de la tâche et les serveurs cibles de la tâche. Cela reflète à peu près les procédures stockées que nous avons exécutées lorsque nous avons créé la tâche.

Consultez la documentation Microsoft pour sp_help_job pour plus d'informations, ainsi qu'une liste d'autres arguments que vous pouvez fournir.

Tester la tâche

Vous pouvez utiliser le sp_start_job procédure stockée pour tester l'exécution de votre travail. Cette procédure accepte le nom ou l'ID de la tâche et exécutera la tâche dès que vous exécuterez la procédure.

Voir Comment exécuter une tâche de l'Agent SQL Server à l'aide de T-SQL pour un exemple.