Sqlserver
 sql >> Base de données >  >> RDS >> Sqlserver

Tronquer toutes les tables d'une base de données dans SQL Server - Tutoriel SQL Server / TSQL Partie 55

Scénario :

Pensons à une base de données que nous utilisons pour notre processus ETL et nous appelons cette base de données intermédiaire. Nous voulons tronquer toutes les tables le matin afin qu'elles puissent être utilisées pour le processus quotidien. Une façon consiste à écrire notre instruction Truncate pour chacune des tables, mais des tables peuvent être supprimées ou de nouvelles tables peuvent également être créées. Nous voulons écrire une requête que nous pouvons utiliser pour tronquer toutes les tables d'une base de données et nous n'avons pas à réécrire nos instructions Truncate.

Si les tables n'ont pas de clé primaire -clé étrangère relation, nous pouvons utiliser Truncate. Mais nous avons souvent des tables qui sont référencées par d'autres tables. Nous ne pouvons pas utiliser l'instruction Truncate pour ces tables. La seule façon de tronquer ces tables est de supprimer la contrainte de clé étrangère avant de tronquer, puis de tronquer et de recréer la relation après cela.

Le code ci-dessous peut être utilisé pour tronquer toutes les tables de la base de données. Si les tables ont la relation Pk-Fk, le script supprimera d'abord les contraintes de clé étrangère, puis tronquera ces tables et enfin recréera les contraintes de clé étrangère.

Avant d'exécuter le script ci-dessous, assurez-vous que vous êtes pointant vers la base de données et le serveur corrects ! Tout le meilleur avec la troncation de toutes les tables d'une base de données SQL Server.


-- Drop Temp Tables if Exists
 IF OBJECT_ID('tempdb..#DropConstraint') IS NOT NULL
  DROP TABLE #DropConstraint
 IF OBJECT_ID('tempdb..#CreateConstraint') IS NOT NULL
  DROP TABLE #CreateConstraint
 IF OBJECT_ID('tempdb..#TempTruncateTables') IS NOT NULL
    DROP TABLE #TempTruncateTables

-- Drop Constraint Script Save in #DropConstraint Temp Table 
SELECT 'ALTER TABLE ' + '['
       + Schema_name(o.schema_id) + '].['
       + OBJECT_NAME(FK.parent_object_id) + ']'
       + ' DROP  CONSTRAINT ' + '[' + FK.name + ']' AS DropConstraintQuery
 INTO   #DropConstraint
 FROM   sys.foreign_keys AS FK
       INNER JOIN sys.foreign_key_columns AS FKC
               ON FK.OBJECT_ID = FKC.constraint_object_id
       INNER JOIN sys.objects O
               ON O.OBJECT_ID = FKC.parent_object_id

-- Create Constraint Script Save in #CreateConstraint Temp Table 
SELECT 'ALTER TABLE ' + '['
       + Schema_name(o.schema_id) + '].' + '['
       + OBJECT_NAME(FK.parent_object_id) + ']'
       + ' ADD CONSTRAINT ' + '[' + FK.name
       + '] Foreign Key (['
       + (SELECT name
          FROM   sys.columns c
          WHERE  c.OBJECT_ID = FKC.parent_object_id
                 AND c.column_id = FKC.parent_column_id)
       + ']) REFERENCES ' + '['
       + Schema_name(o.schema_id) + '].['
       + (SELECT name
          FROM   sys.objects o
          WHERE  OBJECT_ID = FKC.referenced_object_id)
       + '] (['
       + (SELECT name
          FROM   sys.columns c
          WHERE  c.OBJECT_ID = FKC.referenced_object_id
                 AND c.column_id = FKC.referenced_column_id)
       + '])' AS CreateConstraintQuery
 INTO   #CreateConstraint
 FROM   sys.foreign_keys AS FK
       INNER JOIN sys.foreign_key_columns AS FKC
               ON FK.OBJECT_ID = FKC.constraint_object_id
       INNER JOIN sys.objects o
               ON FKC.parent_object_id = o.OBJECT_ID
-- Build Truncate Statement for all the tables and save into #TempTruncateTables
 SELECT 'Truncate table ' + Schema_name(schema_id)
       + '.' + name AS TruncateTableQuery
 INTO   #TempTruncateTables 
FROM   sys.tables
 WHERE  TYPE = 'U'
       AND is_ms_shipped = 0

GO

-- Drop Constraints
 DECLARE @DropConstraintQuery AS VARCHAR(4000)
 DECLARE DropConstraintCur CURSOR FOR
  SELECT DropConstraintQuery
  FROM   #DropConstraint
 OPEN DropConstraintCur 
FETCH Next FROM DropConstraintCur 
 INTO @DropConstraintQuery
 WHILE @@FETCH_STATUS = 0
  BEGIN
      DECLARE @SQL VARCHAR(MAX)=NULL
      SET @SQL=@DropConstraintQuery
      EXEC (@SQL)
      PRINT ' Query ::' + @DropConstraintQuery
            + 'Completed'
      FETCH Next FROM DropConstraintCur INTO @DropConstraintQuery
  END
CLOSE DropConstraintCur 
DEALLOCATE DropConstraintCur
GO-- Truncate tables 
DECLARE @TempTruncateTablesCur AS VARCHAR(4000) 
DECLARE TempTruncateTablesCur CURSOR FOR
  SELECT TruncateTableQuery
  FROM   #TempTruncateTables 
OPEN TempTruncateTablesCur
 FETCH Next FROM TempTruncateTablesCur 
 INTO @TempTruncateTablesCur
 WHILE @@FETCH_STATUS = 0
  BEGIN
      DECLARE @SQL VARCHAR(MAX)=NULL

      SET @SQL=@TempTruncateTablesCur

      EXEC (@SQL)

      PRINT ' Query ::' + @TempTruncateTablesCur
            + 'Completed'
      FETCH Next FROM TempTruncateTablesCur INTO @TempTruncateTablesCur
  END
CLOSE TempTruncateTablesCur 
DEALLOCATE TempTruncateTablesCur
GO


-- Create Constraint After Truncate 
DECLARE @CreateConstraintQuery AS VARCHAR(4000) 
DECLARE CreateConstraintQueryCur CURSOR FOR
  SELECT CreateConstraintQuery
  FROM   #CreateConstraint
 OPEN CreateConstraintQueryCur 
FETCH Next FROM CreateConstraintQueryCur 
 INTO @CreateConstraintQuery 
WHILE @@FETCH_STATUS = 0
  BEGIN
      DECLARE @SQL VARCHAR(MAX)=NULL
      SET @SQL=@CreateConstraintQuery
      EXEC (@SQL)
      PRINT ' Query ::' + @CreateConstraintQuery
            + 'Completed'
      FETCH Next FROM CreateConstraintQueryCur INTO  @CreateConstraintQuery
  END
CLOSE CreateConstraintQueryCur
 DEALLOCATE CreateConstraintQueryCur

GO 



Things we covered in this Post
  • How to drop temp table if exists in SQL Server
  • How to use system tables to get Primary key and foreign key Constraint
  • How to use Cursors in SQL Server 
  • How to Drop Foreign Key Constraints dynamically and Recreate them
  • How to Truncate all tables in SQL Server Database
  • How to use Dynamic SQL in TSQL
  • How to use Variables in TSQL