Impossible de générer une différence à partir du plug-in liquibase gradle

La solution consiste à écrire une tâche graduelle qui invoque liquibase diffChangeLog

Créer un liquibase.gradle fichier dans le répertoire racine du projet, ajoutez l'extension liquibase-hibernate et écrivez une tâche gradle qui appelle le liquibase diffChangeLog commande.

configurations {
  liquibase
}

dependencies {
  liquibase group: 'org.liquibase.ext', name: 'liquibase-hibernate4', version: 3.5
}

//loading properties file.
Properties liquibaseProps = new Properties()
liquibaseProps.load(new FileInputStream("src/main/resources/liquibase-task.properties"))

Properties applicationProps = new Properties()
applicationProps.load(new FileInputStream("src/main/resources/application.properties"))

task liquibaseDiffChangelog(type: JavaExec) {
  group = "liquibase"


  classpath sourceSets.main.runtimeClasspath
  classpath configurations.liquibase
  main = "liquibase.integration.commandline.Main"

  args "--changeLogFile=" + liquibaseProps.getProperty('liquibase.changelog.path')+ buildTimestamp() +"_changelog.xml"
  args "--referenceUrl=hibernate:spring:" + liquibaseProps.getProperty('liquibase.domain.package') + "?dialect=" + applicationProps.getProperty('spring.jpa.properties.hibernate.dialect')
  args "--username=" + applicationProps.getProperty('spring.datasource.username')
  args "--password=" + applicationProps.getProperty('spring.datasource.password')
  args "--url=" + applicationProps.getProperty('spring.datasource.url')
  args "--driver=com.mysql.jdbc.Driver"
  args "diffChangeLog"
}

def buildTimestamp() {
  def date = new Date()
  def formattedDate = date.format('yyyyMMddHHmmss')
  return formattedDate
}

REMARQUE :j'ai utilisé des fichiers de propriétés pour transmettre des arguments à la commande liquibase, vous pouvez ajouter les valeurs directement, mais ce ne serait pas une bonne pratique.

Ensuite, vous devrez appliquer le liquibase.gradle fichier à partir du projet build.gradle dossier. et ajouter la dépendance liquibase

apply from: 'liquibase.gradle'
//code omitted
dependencies {
    compile (group: 'org.liquibase', name: 'liquibase-core', version: "3.4.2")
}

Après cette étape, liquibase serait complètement configuré.