Fonction de conversion d'Oracle vers PostgreSQL

La fonction strpos(str, sub) dans Postgres est équivalent à instr(str, sub) dans Oracle. Malheureusement, la fonction n'a pas de troisième et quatrième paramètres, donc l'expression dans Postgres doit être plus complexe.

La fonction substr(str, n) donne une sous-chaîne de str à partir de n poste.

instr(str, ch, instr(str, sub), 1);                               --oracle
strpos(substr(str, strpos(str, sub)), ch) + strpos(str, sub) - 1; --postgres

Comme instr() est une fonction puissante que je l'ai écrite en plpgsql pour mes propres besoins.

create or replace function instr(str text, sub text, startpos int = 1, occurrence int = 1)
returns int language plpgsql immutable
as $$
declare 
    tail text;
    shift int;
    pos int;
    i int;
begin
    shift:= 0;
    if startpos = 0 or occurrence <= 0 then
        return 0;
    end if;
    if startpos < 0 then
        str:= reverse(str);
        sub:= reverse(sub);
        pos:= -startpos;
    else
        pos:= startpos;
    end if;
    for i in 1..occurrence loop
        shift:= shift+ pos;
        tail:= substr(str, shift);
        pos:= strpos(tail, sub);
        if pos = 0 then
            return 0;
        end if;
    end loop;
    if startpos > 0 then
        return pos+ shift- 1;
    else
        return length(str)- length(sub)- pos- shift+ 3;
    end if;
end $$;

Quelques vérifications (Exemples de Fonctions OLAP DML ):

select instr('Corporate Floor', 'or', 3, 2);  -- gives 14
select instr('Corporate Floor', 'or', -3, 2); -- gives 2

Il n'y a pas de reverse() fonction dans Postgres 8.2. Vous pouvez utiliser ceci :

-- only for Postgres 8.4 or earlier!
create or replace function reverse(str text)
returns text language plpgsql immutable
as $$
declare
    i int;
    res text = '';
begin
    for i in 1..length(str) loop
        res:= substr(str, i, 1) || res;
    end loop;
    return res;
end $$;