Vous semblez être un peu chaotique dans la description du problème, veuillez formater votre question et la rendre plus lisible. Quoi qu'il en soit, les solutions sont simples. Vous n'avez besoin que d'un seul if déclaration, où, selon le niveau, vous recherchez dans le premier ou le deuxième tableau et la colonne appropriée :
create or replace function get_accountdetails (par_input in varchar2) return varchar2 is
v_aid varchar2(10);
v_db varchar2(10);
v_lvl varchar2(10);
v_ret varchar2(20) := '';
begin
v_aid := regexp_substr(par_input, '\d+', 1, 1);
v_db := regexp_substr(par_input, '\d+', 1, 2);
v_lvl := regexp_substr(par_input, '\d+', 1, 3);
if v_lvl = 1 then
select dim_cust_key
into v_ret
from dim_cust_acnt
where level1_account_id = v_aid and database_id = v_db;
elsif v_lvl = 2 then
select dim_cust_key
into v_ret
from dim_cust_dept
where level2_account_id = v_aid and database_id = v_db;
else
select dim_cust_key
into v_ret
from dim_cust_dept
where level3_account_id = v_aid and database_id = v_db;
end if;
return v_ret;
end;
Voici des tableaux et des exemples d'appels de fonction :
create table dim_cust_acnt (dim_cust_key, level1_account_id, database_id) as (
select 1123, 112, 22 from dual union all
select 1234, 113, 23 from dual );
create table dim_cust_dept (dim_cust_key, level2_account_id, level3_account_id, database_id) as (
select 1587, 245, 301, 21 from dual union all
select 1576, 289, 304, 20 from dual);
select get_accountdetails('[112].[22].[1]') from dual; -- result: 1123
select get_accountdetails('[289].[20].[2]') from dual; -- result: 1576
select get_accountdetails('[301].[21].[3]') from dual; -- result: 1587
Veuillez utiliser les noms de colonnes appropriés que vous avez dans vos données réelles et ajuster les types et la longueur des variables si nécessaire. Je pense que vous pouvez également utiliser une requête jointe, aucune fonction spéciale n'est nécessaire, quelque chose comme ci-dessous. J'ai utilisé la full join , car vos exemples ne contiennent pas de lignes correspondantes. Probablement simple join suffira.
with t(par_input) as (select '[112].[22].[1]' from dual)
select dim_cust_key
from dim_cust_acnt a
full join dim_cust_dept d using (dim_cust_key)
cross join t
where ( 1 = regexp_substr(par_input, '\d+', 1, 3)
and regexp_substr(par_input, '\d+', 1, 1) = level1_account_id
and regexp_substr(par_input, '\d+', 1, 2) = a.database_id )
or ( 2 = regexp_substr(par_input, '\d+', 1, 3)
and regexp_substr(par_input, '\d+', 1, 1) = level2_account_id
and regexp_substr(par_input, '\d+', 1, 2) = d.database_id )
or ( 3 = regexp_substr(par_input, '\d+', 1, 3)
and regexp_substr(par_input, '\d+', 1, 1) = level3_account_id
and regexp_substr(par_input, '\d+', 1, 2) = d.database_id )
Résultat :
DIM_CUST_KEY
------------
1123
Si vous supprimez with et cross join pièces et ajouter into clause alors vous pouvez utiliser cette requête dans la fonction au lieu de if déclaration.
Modifier :
Désolé pour le retard, je n'ai pas regardé Stack Overflow dernièrement. Voici deux exemples d'écriture de vos fonctions :
Cette fonction renvoie une chaîne concaténée :
select get_details_1('[112].[22].[1],[289].[20].[2],[301].[21].[3]') as list from dual;
LIST
------------------
1123,1576,1587
Et la deuxième fonction est en pipeline et renvoie les données sous la forme d'une collection prédéfinie de chaînes, de sorte que les valeurs se trouvent dans des lignes séparées.
select column_value
from table(get_details_2('[112].[22].[1],[289].[20].[2],[301].[21].[3]'));
COLUMN_VALUE
------------
1123
1576
1587
Vous pouvez également analyser toutes les données d'entrée dans un premier temps, les stocker dans une collection, puis utiliser la collecte en bloc dans une requête. Il existe de nombreuses solutions et possibilités, personnellement j'utiliserais la fonction en pipeline, mais cela dépend de la forme de sortie dont vous avez besoin (collection ou chaîne concaténée). Vous pouvez également ajouter begin ... end bloquer et gérer l'exception when no_data_found . Vous pouvez alors présenter des informations spéciales ou interrompre l'exécution, cela dépend du comportement attendu dans une telle situation.
Fonction 1 :
create or replace function get_details_1 (par_input in varchar2) return varchar2 is
v_aid varchar2(10);
v_db varchar2(10);
v_lvl varchar2(10);
v_ret varchar2(20);
v_all varchar2(200) := '';
i_cnt int := 0;
begin
loop
v_aid := regexp_substr(par_input, '\d+', 1, i_cnt + 1);
v_db := regexp_substr(par_input, '\d+', 1, i_cnt + 2);
v_lvl := regexp_substr(par_input, '\d+', 1, i_cnt + 3);
i_cnt := i_cnt + 3;
exit when v_aid is null;
select dim_cust_key
into v_ret
from dim_cust_acnt a
full join dim_cust_dept d using (dim_cust_key)
where (v_lvl = 1 and level1_account_id = v_aid and a.database_id = v_db)
or (v_lvl = 2 and level2_account_id = v_aid and d.database_id = v_db)
or (v_lvl = 3 and level3_account_id = v_aid and d.database_id = v_db);
v_all := v_all||','||v_ret;
end loop;
return ltrim(v_all, ',');
end;
Fonction 2 :
create or replace function get_details_2 (par_input in varchar2)
return sys.odcinumberlist pipelined is
v_aid varchar2(10);
v_db varchar2(10);
v_lvl varchar2(10);
v_ret varchar2(20);
i_cnt int := 0;
begin
loop
v_aid := regexp_substr(par_input, '\d+', 1, i_cnt + 1);
v_db := regexp_substr(par_input, '\d+', 1, i_cnt + 2);
v_lvl := regexp_substr(par_input, '\d+', 1, i_cnt + 3);
i_cnt := i_cnt + 3;
exit when v_aid is null;
select dim_cust_key
into v_ret
from dim_cust_acnt a
full join dim_cust_dept d using (dim_cust_key)
where (v_lvl = 1 and level1_account_id = v_aid and a.database_id = v_db)
or (v_lvl = 2 and level2_account_id = v_aid and d.database_id = v_db)
or (v_lvl = 3 and level3_account_id = v_aid and d.database_id = v_db);
pipe row (v_ret);
end loop;
return;
end;
