Comment rendre récursif un bloc de code pl/sql qui fonctionne avec plusieurs phrases selects ?

Vous n'avez pas décrit votre rec type, je vais donc montrer un exemple pour le rendre plus indépendant :

declare
    type t_rec is record(
        param1 varchar2(30),
        param2 varchar2(30),
        param3 varchar2(30),
        param4 varchar2(30),
        param5 varchar2(30)
        );
    rec t_rec;
    v_tx_cuerpo varchar2(4000);
    
    function f_subst(str varchar2, template varchar2, subst ora_name_list_t) return varchar2
    as
        res varchar2(32767):=str;
    begin
        for i in 1..subst.count loop
            res:=replace(res, replace(template,'%d',i), subst(i));
        end loop;
        return res;
    end;
begin
    v_tx_cuerpo:='p1:${param1};p2:${param2};p3:${param3};p4:${param4};p5:${param5};';
    v_tx_cuerpo:=f_subst(
                    v_tx_cuerpo,
                    '${param%d}',
                    ora_name_list_t('str1','str2','str3','str4','str5')
                    );
    dbms_output.put_line(v_tx_cuerpo);
end;
/

comme vous pouvez le voir, j'ai créé la function f_subst qui prend 3 arguments :

• str varchar2 - chaîne d'entrée pour le remplacement
• template varchar2 - masque de chaîne pour le remplacement, dans votre exemple c'est ${param%d}
• subst ora_name_list_t - c'est un collection défini comme TYPE ora_name_list_t IS TABLE OF VARCHAR2(2*(ORA_MAX_NAME_LEN+2)+1) , vous pouvez donc spécifier n'importe quel nombre de chaînes à remplacer. Dans cet exemple, j'ai mis str1 à str5 .

Ainsi, cette fonction itère les éléments de la collection d'entrée et remplace toutes les sous-chaînes qui correspondent à un masque de modèle d'entrée par la valeur de cette collection.

Résultats :

p1:str1;p2:str2;p3:str3;p4:str4;p5:str5;

Et enfin en utilisant votre rec d'origine :

declare
    type t_rec is record(
        param1 varchar2(30),
        param2 varchar2(30),
        param3 varchar2(30),
        param4 varchar2(30),
        param5 varchar2(30)
        );
    rec t_rec;
    v_tx_cuerpo varchar2(4000);
    
    function f_subst(str varchar2, template varchar2, subst ora_name_list_t) return varchar2
    as
        res varchar2(32767):=str;
    begin
        for i in 1..subst.count loop
            res:=replace(res, replace(template,'%d',i), subst(i));
        end loop;
        return res;
    end;
begin
    v_tx_cuerpo:='p1:${param1};p2:${param2};p3:${param3};p4:${param4};p5:${param5};';
    rec.param1:='str1';
    rec.param2:='str2';
    rec.param3:='str3';
    rec.param4:='str4';
    rec.param5:='str5';
    
    v_tx_cuerpo:=f_subst(
                    v_tx_cuerpo,
                    '${param%d}',
                    ora_name_list_t(
                        rec.param1,
                        rec.param2,
                        rec.param3,
                        rec.param4,
                        rec.param5
                        )
                    );
    dbms_output.put_line(v_tx_cuerpo);
end;
/