Dans la grande majorité des cas, la seule façon d'affecter les nouvelles valeurs de la ligne à une variable %ROWTYPE serait d'affecter explicitement chaque colonne. Quelque chose comme
CREATE OR REPLACE TRIGGER some_trigger_name
BEFORE INSERT OR UPDATE ON some_table
FOR EACH ROW
DECLARE
l_row some_table%rowtype;
BEGIN
l_row.column1 := :NEW.column1;
l_row.column2 := :NEW.column2;
...
l_row.columnN := :NEW.columnN;
procedure1( l_row );
procedure2( l_row );
procedure3( l_row );
END;
Si votre table est déclarée sur la base d'un objet, :NEW sera un objet de ce type. Donc, si vous avez un tableau comme
CREATE OR REPLACE TYPE obj_foo
AS OBJECT (
column1 NUMBER,
column2 NUMBER,
...
columnN NUMBER );
CREATE TABLE foo OF obj_foo;
alors vous pourriez déclarer des procédures qui acceptent des paramètres d'entrée de type OBJ_FOO et appelez-les directement depuis votre déclencheur.
Malheureusement, la suggestion dans l'autre fil concernant la sélection de la ligne dans la table dans un fil AFTER INSERT/UPDATE ne fonctionne généralement pas. Cela conduira généralement à une exception de table en mutation.
1 create table foo (
2 col1 number,
3 col2 number
4* )
SQL> /
Table created.
SQL> create procedure foo_proc( p_foo in foo%rowtype )
2 as
3 begin
4 dbms_output.put_line( 'In foo_proc' );
5 end;
6 /
Procedure created.
SQL> create or replace trigger trg_foo
2 after insert or update on foo
3 for each row
4 declare
5 l_row foo%rowtype;
6 begin
7 select *
8 into l_row
9 from foo
10 where col1 = :new.col1;
11 foo_proc( l_row );
12 end;
13 /
Trigger created.
SQL> insert into foo values( 1, 2 );
insert into foo values( 1, 2 )
*
ERROR at line 1:
ORA-04091: table SCOTT.FOO is mutating, trigger/function may not see it
ORA-06512: at "SCOTT.TRG_FOO", line 4
ORA-04088: error during execution of trigger 'SCOTT.TRG_FOO'
