Comment vérifier la version du fournisseur Oracle pour ole-db. Fournisseur OraOLEDB.Oracle

Vous pouvez utiliser par exemple l'outil RegDllView. Recherchez "OraOLEDB", le résultat pourrait être ceci :

Une approche plus simple consisterait à naviguer vers votre ORACE_HOME\bin répertoire et localisez le fichier OraOLEDB??.dll . Vérifiez la version avec le clic droit de la souris -> Propriétés -> Détails.

Cependant, vous obtenez simplement la version du fichier, cela ne signifie pas nécessairement que cette DLL est également enregistrée et prête à l'emploi.

Ou utilisez ce VBScript :

Option Explicit
Const HKEY_CLASSES_ROOT = &H80000000

Dim Key, strComputer, objRegistry, strPath, arrKeys, fso
Dim strKeyPath, strValueName, strValue, uValue, ver

Set fso = CreateObject("Scripting.FileSystemObject")

strComputer = "."
Set objRegistry = GetObject("winmgmts:\\" & strComputer & "\root\default:StdRegProv")
objRegistry.enumKey HKEY_CLASSES_ROOT, "CLSID", arrKeys

For Each key In arrKeys
    strKeyPath = "CLSID\" & key
    strValueName = "OLEDB_SERVICES"
    If objRegistry.GetDWordValue (HKEY_CLASSES_ROOT, strKeyPath, strValueName, uValue) = 0 Then  
        'get the (Default) value which is the name of the provider
        objRegistry.GetStringValue HKEY_CLASSES_ROOT, strKeyPath, "", strValue
        If InStr(1, strValue, "OraOLEDB.Oracle", vbTextCompare) > 0 Then
            ' get expanded location
            objRegistry.GetStringValue HKEY_CLASSES_ROOT, strKeyPath & "\InprocServer32", "", strPath

            ver = fso.GetFileVersion(strPath)
            Wscript.Echo strValue & " @ " & strPath & " -> " & ver
        End If
    End If 
Next

Le fournisseur OLE DB peut exister en 32 bits ou/et en 64 bits, vous pouvez donc exécuter le script deux fois :

C:\Windows\System32\cscript.exe Print_OLE.vbs
C:\Windows\SysWOW64\cscript.exe Print_OLE.vbs