Passer plusieurs lignes de données à une procédure stockée

Vous pouvez diviser plusieurs valeurs à partir d'une seule chaîne assez facilement. Supposons que vous puissiez regrouper la chaîne comme ceci, en utilisant une virgule pour séparer les "colonnes" et un point-virgule pour séparer les "lignes" :

foo, 20120101, 26; bar, 20120612, 32

(Cela suppose que les deux-points et les points-virgules ne peuvent pas apparaître naturellement dans les données ; s'ils le peuvent, vous devrez choisir d'autres délimiteurs.)

Vous pouvez créer une routine de fractionnement comme celle-ci, qui inclut une colonne de sortie qui vous permet de déterminer l'ordre dans lequel la valeur est apparue dans la chaîne d'origine :

CREATE FUNCTION dbo.SplitStrings
(
    @List       NVARCHAR(MAX),
    @Delimiter  NVARCHAR(255)
)
RETURNS TABLE
AS
    RETURN (SELECT Number = ROW_NUMBER() OVER (ORDER BY Number),
        Item FROM (SELECT Number, Item = LTRIM(RTRIM(SUBSTRING(@List, Number, 
        CHARINDEX(@Delimiter, @List + @Delimiter, Number) - Number)))
    FROM (SELECT ROW_NUMBER() OVER (ORDER BY [object_id])
        FROM sys.all_objects) AS n(Number)
    WHERE Number <= CONVERT(INT, LEN(@List))
        AND SUBSTRING(@Delimiter + @List, Number, 1) = @Delimiter
    ) AS y);
GO

Ensuite, vous pouvez l'interroger comme ceci (pour plus de simplicité et d'illustration, je ne gère que 3 propriétés, mais vous pouvez extrapoler cela pour 11 ou n) :

DECLARE @x NVARCHAR(MAX); -- a parameter to your stored procedure

SET @x = N'foo, 20120101, 26; bar, 20120612, 32';

;WITH x AS 
(
    SELECT ID = s.Number, InnerID = y.Number, y.Item 
    -- parameter and "row" delimiter here:
    FROM dbo.SplitStrings(@x, ';') AS s
    -- output and "column" delimiter here:
    CROSS APPLY dbo.SplitStrings(s.Item, ',') AS y
)
SELECT 
    prop1 = x.Item, 
    prop2 = x2.Item, 
    prop3 = x3.Item
FROM x 
INNER JOIN x AS x2 
ON x.InnerID = x2.InnerID - 1
AND x.ID = x2.ID
INNER JOIN x AS x3
ON x2.InnerID = x3.InnerID - 1
AND x2.ID = x3.ID
WHERE x.InnerID = 1
ORDER BY x.ID;

Résultats :

prop1   prop2     prop3
------  --------  -------
foo     20120101  26
bar     20120612  32