SQL Server - Auto-incrémentation qui autorise les instructions UPDATE

Une solution à ce problème de "Inside Microsoft SQL Server 2008 :T-SQL Querying"

CREATE TABLE dbo.Sequence(
 val int IDENTITY (10000, 1) /*Seed this at whatever your current max value is*/
 )

GO

CREATE PROC dbo.GetSequence
@val AS int OUTPUT
AS
BEGIN TRAN
    SAVE TRAN S1
    INSERT INTO dbo.Sequence DEFAULT VALUES
    SET @val=SCOPE_IDENTITY()
    ROLLBACK TRAN S1 /*Rolls back just as far as the save point to prevent the 
                       sequence table filling up. The id allocated won't be reused*/
COMMIT TRAN

Ou une autre alternative du même livre qui alloue des gammes plus facilement. (Vous devez déterminer si vous souhaitez l'appeler de l'intérieur ou de l'extérieur de votre transaction - l'intérieur bloquerait d'autres transactions simultanées jusqu'à ce que la première soit validée)

CREATE TABLE dbo.Sequence2(
 val int 
 )

GO

INSERT INTO dbo.Sequence2 VALUES(10000);

GO

CREATE PROC dbo.GetSequence2
@val AS int OUTPUT,
@n as int =1
AS
UPDATE dbo.Sequence2 
SET @val = val = val + @n;

SET @val = @val - @n + 1;