Fractionnement des valeurs délimitées dans une colonne SQL en plusieurs lignes

Si vous êtes sur SQL Server 2016+

Vous pouvez utiliser le nouveau STRING_SPLIT fonction, sur laquelle j'ai blogué ici, et Brent Ozar a blogué ici.

SELECT s.[message-id], f.value
  FROM dbo.SourceData AS s
  CROSS APPLY STRING_SPLIT(s.[recipient-address], ';') as f;

Si vous êtes toujours sur une version antérieure à SQL Server 2016

Créez une fonction de fractionnement. Ce n'est qu'un exemple parmi tant d'autres :

CREATE FUNCTION dbo.SplitStrings
(
    @List       NVARCHAR(MAX),
    @Delimiter  NVARCHAR(255)
)
RETURNS TABLE
AS
    RETURN (SELECT Number = ROW_NUMBER() OVER (ORDER BY Number),
        Item FROM (SELECT Number, Item = LTRIM(RTRIM(SUBSTRING(@List, Number, 
        CHARINDEX(@Delimiter, @List + @Delimiter, Number) - Number)))
    FROM (SELECT ROW_NUMBER() OVER (ORDER BY s1.[object_id])
        FROM sys.all_objects AS s1 CROSS APPLY sys.all_objects) AS n(Number)
    WHERE Number <= CONVERT(INT, LEN(@List))
        AND SUBSTRING(@Delimiter + @List, Number, 1) = @Delimiter
    ) AS y);
GO

J'en ai discuté de quelques autres ici, ici, et d'une meilleure approche que de diviser en premier lieu ici.

Maintenant, vous pouvez extrapoler simplement en :

SELECT s.[message-id], f.Item
  FROM dbo.SourceData AS s
  CROSS APPLY dbo.SplitStrings(s.[recipient-address], ';') as f;

Aussi, je suggère de ne pas mettre de tirets dans les noms de colonnes. Cela signifie que vous devez toujours les mettre entre [square brackets] .