Erreur (ORA-21700) avec l'opérateur de table après la mise à jour vers Oracle 12.2 à partir de 12.1

J'ai rencontré le même problème ou un problème similaire après la mise à niveau d'Oracle 12c vers 19c. Je ne sais pas pourquoi la mise à niveau d'Oracle a causé un problème, et je ne comprends pas non plus pourquoi mon correctif fonctionne !

Dans mes procédures stockées, où la fonction TABLE d'Oracle est appliquée à une entrée de procédure stockée, j'obtiens l'erreur :"ORA-21700 :l'objet n'existe pas ou est marqué pour suppression".

Cependant, lorsque la fonction TABLE d'Oracle a été appliquée à une variable locale dans la procédure stockée, il n'y a pas eu d'erreur. Donc, ma solution de contournement consistait simplement à attribuer des entrées de procédure stockée à des variables locales, avant d'utiliser la fonction TABLE, et cela a en quelque sorte résolu le problème !

CREATE OR REPLACE PACKAGE my_types IS
  TYPE integers IS TABLE OF NUMBER INDEX BY BINARY_INTEGER;
  TYPE reals    IS TABLE OF FLOAT INDEX BY BINARY_INTEGER;
END my_types;
/

CREATE OR REPLACE PROCEDURE order_list
(
  i_order_numbers  IN  my_types.integers,
  o_order_numbers  OUT my_types.integers,
  o_order_values   OUT my_types.reals
)
IS

  r_order_numbers  my_types.integers;

  CURSOR order_list_cur (p_order_numbers my_types.integers)
      IS
  SELECT order_number, order_value
    FROM orders
   WHERE order_number IN (SELECT * FROM TABLE(p_order_numbers))
  ;
  order_list_rec  order_list_cur%ROWTYPE;

  rec_no BINARY_INTEGER;

BEGIN

  r_order_numbers := i_order_numbers;

  rec_no := 0;

  OPEN order_list_cur(r_order_numbers);
  LOOP
    FETCH order_list_cur INTO order_list_rec;
    EXIT WHEN order_list_cur%NOTFOUND;
      rec_no := rec_no + 1;
       o_order_numbers(rec_no) := order_list_rec.order_number;
       o_order_values(rec_no) := order_list_rec.order_value;
  END LOOP;
  CLOSE order_list_cur;

END order_list;