Oracle :Existe-t-il un moyen d'obtenir les erreurs de syntaxe SQL récentes ?

Vous pouvez créer un déclencheur dans Oracle qui consignera toutes les erreurs (ou à peu près toutes - NO_DATA_FOUND n'est pas considéré comme une erreur). Dans l'exemple ci-dessous, toute erreur dans le schéma est enregistrée dans la table TRACK_DETAIL (erreur dans une ligne, échec SQL dans la suivante). Vous pouvez le rendre plus sophistiqué avec un numéro de séquence, une date/heure, etc.

create table track_detail (val varchar2(4000));

create or replace procedure track (p_text IN VARCHAR2) IS
  PRAGMA AUTONOMOUS_TRANSACTION;
begin
  insert into track_detail(val)
  values (p_text);
  commit;
end;
.
/
create or replace TRIGGER log_err after servererror on schema
DECLARE
  v_temp VARCHAR2(2000) := substr(dbms_utility.format_error_stack,1,2000);
  v_num NUMBER;
  v_sql_text ora_name_list_t;
begin
  v_temp := translate(v_temp,'''','"');
  track(v_temp);
  v_num  := ora_sql_txt(v_sql_text);
  v_temp := null;
  BEGIN
    FOR i IN 1..v_num LOOP
      v_temp := v_temp || v_sql_text(i);
    END LOOP;
  EXCEPTION
    WHEN VALUE_ERROR THEN NULL;
  END;
  v_temp := translate(v_temp,''''||chr(0)||chr(10),'"');
  track(v_temp);
end;
/

N'oubliez pas de supprimer (ou de désactiver) le déclencheur lorsque vous en avez terminé.