Oracle :convertir le montant de la devise en mots à l'aide de PL/SQL

Ci-dessous, je donne un exemple de fonction stockée Oracle pour convertir le montant de la devise en mots à l'aide de PL/SQL. Par exemple, le montant de 123,45 $ se traduirait par cent vingt-trois dollars et quarante-cinq cents. En outre, vous pouvez modifier la devise en fonction, par exemple, Roupies et Paise.

Fonction Oracle PL/SQL pour convertir le montant en devise en mots

La fonction stockée Oracle PL/SQL suivante accepte un argument numérique et n'a aucune limitation. Un nombre peut être un nombre décimal, entier et négatif. La fonction amount_in_words a une fonction à l'intérieur de check_if_single , et la fonction check_if_single a un n_spell fonction à l'intérieur pour convertir le montant de la devise en mots. Je pensais créer un package au lieu de cette fonction, mais je pensais que seule une fonction serait plus facile à maintenir.

CREATE OR REPLACE FUNCTION amount_in_words (i_amt IN NUMBER)
   RETURN VARCHAR2
IS
   n_dollar   NUMBER;
   n_cents    NUMBER;

   FUNCTION check_if_single (i_num IN NUMBER, currency IN VARCHAR2)
      RETURN VARCHAR2
   IS
      FUNCTION n_spell (i_num IN NUMBER)
         RETURN VARCHAR2
      AS
         TYPE w_Array IS TABLE OF VARCHAR2 (255);

         l_str w_array
               := w_array ('',
                           ' thousand ',
                           ' million ',
                           ' billion ',
                           ' trillion ',
                           ' quadrillion ',
                           ' quintillion ',
                           ' sextillion ',
                           ' septillion ',
                           ' octillion ',
                           ' nonillion ',
                           ' decillion ',
                           ' undecillion ',
                           ' duodecillion ');

         l_num           VARCHAR2 (50) DEFAULT TRUNC (i_num);
         l_is_negative   BOOLEAN := FALSE;
         l_return        VARCHAR2 (4000);
      BEGIN
         IF SIGN (i_num) = -1
         THEN
            l_is_negative := TRUE;
            l_num := TRUNC (ABS (i_num));
         END IF;

         FOR i IN 1 .. l_str.COUNT
         LOOP
            EXIT WHEN l_num IS NULL;

            IF (SUBSTR (l_num, LENGTH (l_num) - 2, 3) <> 0)
            THEN
               l_return :=
                  TO_CHAR (
                     TO_DATE (SUBSTR (l_num, LENGTH (l_num) - 2, 3), 'J'),
                     'Jsp')
                  || l_str (i)
                  || l_return;
            END IF;

            l_num := SUBSTR (l_num, 1, LENGTH (l_num) - 3);
         END LOOP;

         IF NOT l_is_negative
         THEN
            RETURN INITCAP (l_return);
         ELSE
            RETURN 'Negative ' || INITCAP (l_return);
         END IF;
      END n_spell;
   BEGIN
      IF i_num = 1
      THEN
         RETURN 'One ' || currency;
      ELSE
         RETURN n_spell (i_num) || ' ' || currency;
      END IF;
   END check_if_single;
BEGIN
   IF i_amt IS NULL
   THEN
      RETURN '';
   END IF;

   n_dollar := TRUNC (i_amt);
   n_cents := (ABS (i_amt) - TRUNC (ABS (i_amt))) * 100;

   IF NVL (n_cents, 0) > 0
   THEN
      RETURN    check_if_single (n_dollar, 'Dollar')
             || ' and '
             || check_if_single (n_cents, 'Cents');
   ELSE
      RETURN check_if_single (n_dollar, 'Dollar');
   END IF;
END amount_in_words;
/

Tester

SELECT amount_in_words (89378.58) FROM DUAL;

Sortie

Eighty-Nine Thousand Three Hundred Seventy-Eight Dollar and Fifty-Eight Cents

Test via un tableau

SELECT client_code,
       balance_amt,
       amount_in_words (balance_amt) balance_amount_in_words
  FROM account_balance;

Sortie

Vous pouvez changer la devise lorsque vous appelez le check_if_single fonction de amount_in_words une fonction. Par exemple, j'ai remplacé Roupies et Paise dans la partie suivante du code PL/SQL :

 IF NVL (n_cents, 0) > 0
   THEN
      RETURN    check_if_single (n_dollar, 'Rupees')
             || ' and '
             || check_if_single (n_cents, 'Paise');
   ELSE
      RETURN check_if_single (n_dollar, 'Rupees');
   END IF;

Testez après avoir effectué la modification

SELECT amount_in_words (7836.58) in_words FROM DUAL;

Sortie

Seven Thousand Eight Hundred Thirty-Six Rupees and Fifty-Eight Paise

Peut-être avez-vous besoin de déplacer le mot Roupies de la fin à la position de départ de la ligne en fonction du format de votre devise et qui peut être facilement modifié dans la fonction ci-dessus.

Voir aussi :

• Utilitaire :générer une procédure PL/SQL pour exporter des données à partir d'une table en 2 minutes