APEX_ZIP Exemple

À partir d'Oracle 12c, sur lequel Oracle Apex est installé par défaut, vous pouvez utiliser APEX_ZIP Package PL/SQL pour compresser les fichiers. Donc ici, je donne quelques Oracle APEX_ZIP exemples :

Exemple Oracle APEX_ZIP

Le code PL/SQL suivant récupère les fichiers (BLOB ) à partir d'une table et compressez-la, et vous donne un BLOB final qui contient tous les fichiers que vous avez ajoutés.

declare
   b_zip_file blob;

   cursor c_files
    is
    select file_name,
    file_content
    from emp_files
       where empno = 7894;

begin
   for c in c_files 
   loop
      -- adds the each blob to b_zip_file blob one by one
      apex_zip.add_file (
      p_zipped_blob => b_zip_file,
      p_file_name => c.file_name,
      p_content => c.file_content );
   end loop;

   -- finalizes the blob
   apex_zip.finish (
     p_zipped_blob => b_zip_file );

end;

Vous pouvez voir dans le code ci-dessus qu'à la fin, vous obtiendrez le BLOB final que vous pouvez ensuite stocker dans la table ou l'envoyer à une procédure ou écrire un fichier sur le serveur.

L'exemple suivant est un ajout au code ci-dessus. Après avoir compressé les fichiers, il écrira le fichier zip sur le serveur.

 Zipez les fichiers à l'aide du package APEX_ZIP et écrivez sur le serveur

Pour écrire le fichier sur le serveur, vous avez besoin d'un objet Oracle Directory. Vous trouverez ci-dessous un exemple de création d'un objet répertoire dans Oracle pointant vers un répertoire sur le serveur.

Create or Replace directory my_dir as '/your/server/path';

Après avoir créé le répertoire, vous pouvez écrire le fichier zip comme indiqué dans l'exemple ci-dessous :

declare
   b_zip_file blob;

   -- variables for writing the files
   l_file       UTL_FILE.file_type;
   l_buffer     RAW (32767);
   l_amount     BINARY_INTEGER := 32767;
   l_pos        INTEGER := 1;
   l_blob_len   INTEGER;
   -- end variable declaration for file
   cursor c_files
    is
    select file_name,
    file_content
    from emp_files
       where empno = 7894;
begin
   for c in c_files 
   loop
      -- adds the each blob to b_zip_file blob one by one
      apex_zip.add_file (
      p_zipped_blob => b_zip_file,
      p_file_name => c.file_name,
      p_content => c.file_content );
   end loop;

   -- finalizes the blob
   apex_zip.finish (
     p_zipped_blob => b_zip_file );
   
   -- write the file
   l_blob_len := DBMS_LOB.getlength (b_zip_file);

   l_file :=
      UTL_FILE.fopen ('MY_DIR',
                     'my_zip.zip',
                      'WB',
                      32767);

   WHILE l_pos < l_blob_len
   LOOP

      DBMS_LOB.read (b_zip_file,
                     l_amount,
                     l_pos,
                     l_buffer);
      UTL_FILE.put_raw (l_file, l_buffer, TRUE);
      l_pos := l_pos + l_amount;
   END LOOP;

   UTL_FILE.fclose (l_file);
end;

Après avoir exécuté le code PL/SQL ci-dessus, vous trouverez le fichier my_zip.zip au MY_DIR emplacement du répertoire sur le serveur.

Tutoriels associés :

• Comment obtenir un BLOB à partir d'un fichier en PL/SQL ?
• Comment décompresser un fichier en PL/SQL ?

Référence :

• Manuel Oracle APEX_ZIP