comment appeler un service web depuis t-sql

Vous devez utiliser SQLCLR ou un programme externe pour cela. Dans SQL 20106, vous pouvez utiliser R à partir de TSQL, et dans SQL 2017, vous pouvez également utiliser Python. C'est rarement une bonne idée de faire des appels de service Web à partir de TSQL, et si vous le faites, vous devriez généralement tirer d'une file d'attente. Dans ce cas, vous pouvez utiliser un programme externe.

Les procs sp_oaxxx sont anciennes, difficiles à utiliser, peu connues, nécessitent une configuration serveur dangereuse, etc, etc.

Cela étant dit, voici un code que j'ai extrait de Usenet et que j'ai écrit il y a très, très longtemps :

create procedure http_get( @sUrl varchar(200), @response varchar(8000) out)
As
begin
    Declare
      @obj   int
     ,@hr   int
     ,@status int
     ,@msg varchar(255)

       exec @hr = sp_OACreate 'MSXML2.ServerXMLHttp', @obj OUT
       if @hr < 0 begin Raiserror('sp_OACreate MSXML2.ServerXMLHttp failed', 16,1) return 1 end
       exec @hr = sp_OAMethod @obj, 'Open', NULL, 'GET', @sUrl, false
       if @hr <0 begin set @msg = 'sp_OAMethod Open failed' goto eh end
       exec @hr = sp_OAMethod @obj, 'send'
       if @hr <0 begin  set @msg = 'sp_OAMethod Send failed' goto eh end
       exec @hr = sp_OAGetProperty @obj, 'status', @status OUT
       if @hr <0 begin  set @msg = 'sp_OAMethod read status failed' goto eh end
       if @status <> 200  begin set @msg = 'sp_OAMethod http status ' + str(@status) goto eh end
       exec @hr = sp_OAGetProperty @obj, 'responseText', @response OUT
       if @hr <0 begin  set @msg = 'sp_OAMethod read response failed' goto eh end
       exec @hr = sp_OADestroy @obj
       return 0
    eh:
      exec @hr = sp_OADestroy @obj
      Raiserror(@msg, 16, 1)
      return 1
end